### 配置 APT 软件仓库
运行自己的软件仓库有几个优点。你可以在自己的仓库中发布自己的软件包。 你可以在自己的软件仓库中放置上游软件包或第三方软件包，从而控制你使用的软件版本。 你可以将自己的软件仓库放置在其他服务器附近，从而避免网速缓慢或镜像站点无法访问的问题。
即使你不需要创建自己的软件包，也可能想要下载特定版本软件包所需的关键依赖包， 并将这些依赖包存储在自己的仓库中，从而防止因上游发生变故而产生的任何意外 （例如，你的发行版本已到达生命周期的终结或者上游仓库已经被关闭）。
这也使得通过 Puppet 自动更新软件包便得更容易。你可能偶尔需要更新一个软件包 （例如，当有一个安全更新可用时），只要在 package 资源中指定 ensure => latest 就可以方便地实现包更新。但是如果你不能控制仓库，就可能遭遇意想不到的升级风险， 使你的系统受到某种破坏。
使用自己的软件仓库是件两全其美的事情：你可以放心地使用 Puppet 从自己的软件仓库自动更新软件包，当有新版本的软件可用时，只需要将其纳入自己的软件仓库； 你可以首先测试上游的软件版本，确保其可用的情况下再纳入用于生产环境的软件仓库。
#### 准备工作
你需要第 9 章 [管理 Apache 服务](#ch07sec01) 一节中讲述的 apache 模块， 如果还没有此模块请先创建它。
在本例中，我将我的仓库命名为 packages.bitfieldconsulting.com。 你可能想要使用一个不同的仓库名，这需要替换本例中的所有的仓库名 packages.bitfieldconsulting.com 为你想要的仓库名。
#### 操作步骤
1. 创建一个新的 repo 模块：
```
# mkdir /etc/puppet/modules/repo
# mkdir /etc/puppet/modules/repo/manifests
# mkdir /etc/puppet/modules/repo/files
```
2. 使用如下内容创建 /etc/puppet/modules/repo/manifests/bitfield-server.pp 文件：
```
class repo::bitfield-server {
include apache
package { "reprepro": ensure => installed }
file { [ "/var/apt",
"/var/apt/conf" ]:
ensure => directory,
}
file { "/var/apt/conf/distributions":
source => "puppet:///modules/repo/distributions",
require => File["/var/apt/conf"],
}
file { "/etc/apache2/sites-available/apt-repo":
source => "puppet:///modules/repo/apt-repo.conf",
require => Package["apache2-mpm-worker"],
}
file { "/etc/apache2/sites-enabled/apt-repo":
ensure => symlink,
target => "/etc/apache2/sites-available/apt-repo",
require => File["/etc/apache2/sites-available/apt-repo"],
notify => Service["apache2"],
}
}
```
3. 使用如下内容创建 /etc/puppet/modules/repo/files/distributions 文件：
```
Origin: Bitfield Consulting
Label: bitfield
Suite: stable
Codename: lucid
Architectures: amd64 i386
Components: main non-free contrib
Description: Custom and cached packages for Bitfield Consulting
```
4. 使用如下内容创建 /etc/puppet/modules/repo/files/apt-repo.conf 文件：
```
<VirtualHost *:80>
DocumentRoot /var/apt
ServerName packages.bitfieldconsulting.com
ErrorLog /var/log/apache2/packages.bitfieldconsulting.com.error.log
LogLevel warn
CustomLog /var/log/apache2/packages.bitfieldconsulting.com.access.log combined
ServerSignature On
# Allow directory listings so that people can browse the
# repository from their browser too
<Directory "/var/apt">
Options Indexes FollowSymLinks MultiViews
DirectoryIndex index.html
AllowOverride Options
Order allow,deny
allow from all
</Directory>
# Hide the conf/ directory for all repositories
<Directory "/var/apt/conf">
Order allow,deny
Deny from all
Satisfy all
</Directory>
# Hide the db/ directory for all repositories
<Directory "/var/apt/db">
Order allow,deny
Deny from all
Satisfy all
</Directory>
</VirtualHost>
```
5. 在一个节点的配置清单中添加如下代码：
```
include repo::bitfield-server
```
6. 运行 Puppet：
```
# puppet agent --test
info: Retrieving plugin
info: Caching catalog for cookbook.bitfieldconsulting.com
info: Applying configuration version '1304775601'
notice: /Stage[main]/Repo::Bitfield-server/File[/var/apt]/ensure:
created
notice: /Stage[main]/Repo::Bitfield-server/File[/var/apt/conf]/
ensure: created
notice: /Stage[main]/Repo::Bitfield-server/File[/var/apt/conf/
distributions]/ensure: defined content as '{md5}65dc791b876f53318a
35fcc42c770283'
notice: /Stage[main]/Repo::Bitfield-server/Package[reprepro]/
ensure: created
notice: /Stage[main]/Repo::Bitfield-server/File[/etc/apache2/
sites-enabled/apt-repo]/ensure: created
notice: /Stage[main]/Repo::Bitfield-server/File[/etc/apache2/
sites-available/apt-repo]/ensure: defined content as '{md5}2da4686
957e5acf49220047fe6f6e6e1'
info: /Stage[main]/Repo::Bitfield-server/File[/etc/apache2/sitesenabled/
apt-repo]: Scheduling refresh of Service[apache2]
notice: /Stage[main]/Apache/Service[apache2]: Triggered 'refresh'
from 1 events
notice: Finished catalog run in 16.32 seconds
```
#### 工作原理
其实，你无需创建一个 APT 仓库。因为可以通过 HTTP 下载软件包，所以你只需要一个 Apache 虚拟主机。 你可以将实际的软件包随意放置在任何地方，只要有一个 conf/distributions 文件并在其中给出 APT 仓库的相关信息。
1. bitfield-server 类的第一部分确保 Apache 已经被设置：
```
class repo::bitfield-server {
include apache
```
2. reprepro 是用于管理仓库本身的非常有用的工具（例如，添加一个新的软件包）：
```
package { "reprepro": ensure => installed }
```
3. 我们创建一个仓库的根目录 /var/apt，以及该目录下的 conf/distributions 文件：
```
file { [ "/var/apt",
"/var/apt/conf" ]:
ensure => directory,
}
file { "/var/apt/conf/distributions":
source => "puppet:///modules/repo/distributions",
require => File["/var/apt/conf"],
}
```
4. 这个类的其余部分部署了一个 Apache 虚拟主机的配置文件，用于响应 packages.bitfieldconsulting.com 的请求：
```
file { "/etc/apache2/sites-available/apt-repo":
source => "puppet:///modules/repo/apt-repo.conf",
require => Package["apache2-mpm-worker"],
}
file { "/etc/apache2/sites-enabled/apt-repo":
ensure => symlink,
target => "/etc/apache2/sites-available/apt-repo",
require => File["/etc/apache2/sites-available/apt-repo"],
notify => Service["apache2"],
}
```
#### 更多用法
当然，一个可用的仓库里不能没有软件包。下面将介绍如何添加软件包， 以及如何配置主机并从你的仓库下载软件包。
##### 向仓库添加软件包
要添加一个软件包到你的仓库，首先下载它然后使用 reprepro 将其添加到仓库：
```
# cd /tmp
# wget http://archive.ubuntu.com/ubuntu/pool/main/n/ntp/\
ntp_4.2.4p8+dfsg-1ubuntu2.1_i386.deb
# cd /var/apt
# reprepro includedeb lucid /tmp/ntp_4.2.4p8+dfsg-1ubuntu2.1_i386.deb
Exporting indices...
```
##### 配置节点使用仓库
1. 使用如下内容创建 /etc/puppet/modules/repo/manifests/bitfield.pp 文件 （请根据你自己的仓库服务器的 IP 地址替换如下的 IP 地址）：
```
class repo::bitfield {
host { "packages.bitfieldconsulting.com":
ip => "10.0.2.15",
ensure => present,
target => "/etc/hosts",
}
file { "/etc/apt/sources.list.d/bitfield.list":
content => "deb http://packages.bitfieldconsulting.com/lucid main\n",
require => Host["packages.bitfieldconsulting.com"],
notify => Exec["bitfield-update"],
}
exec { "bitfield-update":
command => "/usr/bin/apt-get update",
require => File["/etc/apt/sources.list.d/bitfield.list"],
refreshonly => true,
}
}
```
如果你有 DNS 服务器或者你可以控制你的 DNS 区域，可以省略 host 资源的设置。
2. 应用这个类到一个节点：
```
node cookbook {
include repo::bitfield
}
```
3. 测试你仓库中的 ntp 软件包是否可用：
```
# apt-cache madison ntp
ntp | 1:4.2.4p8+dfsg-1ubuntu2.1 | http://us.archive.ubuntu.
com/ubuntu/ lucid-updates/main Packages
ntp | 1:4.2.4p8+dfsg-1ubuntu2.1 | http://packages.
bitfieldconsulting.com/ lucid/main Packages
ntp | 1:4.2.4p8+dfsg-1ubuntu2 | http://us.archive.ubuntu.
com/ubuntu/ lucid/main Packages
ntp | 1:4.2.4p8+dfsg-1ubuntu2 | http://us.archive.ubuntu.
com/ubuntu/ lucid/main Sources
ntp | 1:4.2.4p8+dfsg-1ubuntu2.1 | http://us.archive.ubuntu.
com/ubuntu/ lucid-updates/main Sources
```
##### 对软件包签名
对于生产环境，你应该对软件仓库设置 GPG 密钥并且对软件包进行签名，关于如何设置密钥和签名的信息， 请参考 Sander Marechal 撰写的关于 “设置和管理 APT 仓库” 的文章： [http://www.jejik.com/articles/2006/09/setting_up_and_managing_an_apt_repository_with_reprepro/](http://www.jejik.com/articles/2006/09/setting_up_and_managing_an_apt_repository_with_reprepro/) 。
- Puppet 2.7 Cookbook 中文版
- 中文翻译版
- 译者序
- 项目缘起
- 翻译方法
- 社区链接
- 社区建议
- 贡献者
- 原书版权页
- 关于作者
- 前言
- 本书内容
- 阅读前提
- 适用读者
- 格式约定
- 读者反馈
- 客户支持
- 下载案例代码
- 勘误表
- Puppet 基础设施
- 使用版本控制
- 使用提交钩子
- 使用 Rake 部署变更
- 配置 Puppet 的文件服务器
- 从 cron 运行 Puppet
- 使用自动签名
- 预签名证书
- 从 Puppet 的 filebucket 检索文件
- 使用 Passenger 扩展 Puppet 的部署规模
- 创建去中心化的分布式 Puppet 架构
- 监控、报告和排错
- 生成报告
- 通过 Email 发送包含特定标签的日志信息
- 创建图形化报告
- 自动生成 HTML 文档
- 绘制依赖关系图
- 测试你的 Puppet 配置清单
- 执行模拟运行
- 检测编译错误
- 理解 Puppet 的错误信息
- 显示命令的输出结果
- 输出调试信息
- 检查配置设置
- 使用标签
- 使用运行阶段
- 使用不同的环境
- Puppet 语言及其写作风格
- 使用 Puppet 社区规范
- 使用模块
- 使用标准的命名规范
- 使用嵌入式 Ruby 代码
- 使用纯 Ruby 代码书写配置清单
- 遍历多个项目
- 书写强大的条件语句
- 在 if 语句中使用正则表达式
- 使用选择器和 case 语句
- 检测字符串中是否包含指定的值
- 使用正则表达式替换
- 书写更优质的配置清单
- 使用资源的数组
- 使用 define 资源
- 指定资源的依赖关系
- 使用节点继承
- 使用类的继承和重载
- 给类传递参数
- 书写可重用的跨平台配置清单
- 获得系统的环境信息
- 导入动态信息
- 从 CSV 文件导入数据
- 给 Shell 命令传递参数
- 使用文件和软件包
- 为配置文件添加配置行
- 使用 Augeas 自动修改配置文件
- 使用配置片段构建配置文件
- 使用 ERB 模板
- 在模板中遍历数组
- 从第三方仓库安装软件包
- 配置 APT 软件仓库
- 配置 GEM 仓库
- 从源码包自动构建软件
- 比较软件包的版本
- 用户和虚拟资源
- 使用虚拟资源
- 使用虚拟资源管理用户
- 管理用户基于密钥的 SSH 访问
- 管理用户的自定义文件
- 有效地分发 cron 任务
- 当文件更新时运行命令
- 使用主机资源
- 为文件资源指定多个源
- 使用文件资源递归地分发整个目录树
- 清理过期的旧文件
- 使用日程表资源
- 资源的审计
- 临时禁用资源
- 管理时区
- 应用程序
- 管理 Apache 服务
- 创建 Apache 虚拟主机
- 创建 Nginx 虚拟主机
- 创建 MySQL 数据库及用户
- 管理 Drupal 站点
- 管理 Rails 应用程序
- 服务器和云基础设施
- 部署 Nagios 监控服务器
- 使用 Heartbeat 构建高可用服务
- 管理 NFS 服务和文件共享
- 使用 HAProxy 为多个 web 服务器实现负载均衡
- 使用 iptables 管理防火墙
- 管理 Amazon 的 EC2 实例
- 使用 Vagrant 管理虚拟机
- 外部工具和 Puppet 生态环境
- 创建 Facter 的自定义 fact
- 在运行 Puppet 之前和之后执行命令
- 从 Shell 会话生成 Puppet 配置清单
- 从运行的系统上生成 Puppet 配置清单
- 使用 Puppet Dashboard
- 使用 Foreman
- 使用 MCollective
- 使用公共模块
- 使用外部节点分类器
- 创建自定义的资源类型
- 创建自定义的提供者